cd H:\Giovanni\MyPapers\Peri_Ottaviano_aggregate\REDUX_2008\empirics\CPS_regressions
capture log close
clear

use hours_63_07
sort year edu
merge year edu using wages_63_07 hours_63_07_hisp hours_63_07_immi
drop _merge* 
drop hours_nonw employment_nonw
rename hours_immgrants hours_immigrants

*** reshape the data by year only
reshape wide hours employment obs weekly hourly hours_hisp employment_hisp hours_immigrants employment_immigrants, i(year) j(edu)
for any hours employment obs weekly hourly hours_hisp employment_hisp hours_immigrants employment_immigrants: ren X1 X_HSD
for any hours employment obs weekly hourly hours_hisp employment_hisp hours_immigrants employment_immigrants: ren X2 X_HSG
for any hours employment obs weekly hourly hours_hisp employment_hisp hours_immigrants employment_immigrants: ren X3 X_COD
for any hours employment obs weekly hourly hours_hisp employment_hisp hours_immigrants employment_immigrants: ren X4 X_COG

*** generate the relative wages and supply
*** KATZ and MURPHY

gen lnwage_w_CO_HS=ln(weekly_COG/weekly_HSG)

gen lnsupply_CO_HS_1=ln((hours_COG+0.29*hours_COD)/(0.69*hours_COD+hours_HSG+0.93*hours_HSD))
gen lnsupply_CO_HS_2=ln((hours_COG+hours_COD)/(hours_HSG+hours_HSD))

gen lnempl_CO_HS_1=ln((employment_COG+0.29*employment_COD)/(0.69*employment_COD+employment_HSG+0.93*employment_HSD))
gen lnempl_CO_HS_2=ln((employment_COG+employment_COD)/(employment_HSG+employment_HSD))

** HSD and HS
gen lnwage_w_HS_HSD=ln(weekly_HSG/weekly_HSD)
gen lnsupply_HS_HSD=ln((hours_HSG)/(hours_HSD))
gen lnempl_HS_HSD=ln((employment_HSG)/(employment_HSD))

** COG and COD
gen lnwage_w_COG_COD=ln(weekly_COG/weekly_COD)
gen lnsupply_COG_COD=ln((hours_COG)/(hours_COD))
gen lnempl_COG_COD=ln((employment_COG)/(employment_COD))

gen obs=obs_HSD+obs_HSG+obs_COG+obs_COD
gen time=year-1962
tsset year

***Table 6
** column 1
reg lnwage_w_CO_HS time lnsupply_CO_HS_1 [aw=obs], robust
newey lnwage_w_CO_HS time lnsupply_CO_HS_1 [aw=obs], lag(1)

reg lnwage_w_CO_HS time lnsupply_CO_HS_2 [aw=obs], robust
newey lnwage_w_CO_HS time lnsupply_CO_HS_2 [aw=obs], lag(1)

reg lnwage_w_CO_HS time lnempl_CO_HS_1 [aw=obs], robust
newey lnwage_w_CO_HS time lnempl_CO_HS_1 [aw=obs], lag(1)

reg lnwage_w_CO_HS time lnsupply_CO_HS_1 if year>=1970, robust
newey lnwage_w_CO_HS time lnsupply_CO_HS_1 if year>=1970, lag(1)



** Column 2 HSD and HSG
reg lnwage_w_HS_HSD time lnsupply_HS_HSD [aw=obs], robust
newey lnwage_w_HS_HSD time lnsupply_HS_HSD [aw=obs], lag(1)
test lnsupply_HS_HSD==0.32
reg lnwage_w_HS_HSD time lnempl_HS_HSD [aw=obs],  robust
newey lnwage_w_HS_HSD time lnempl_HS_HSD [aw=obs],  lag(1)

reg lnwage_w_HS_HSD time lnempl_HS_HSD if year>=1970 [aw=obs], robust
newey lnwage_w_HS_HSD time lnempl_HS_HSD if year>=1970 [aw=obs], lag(1)


**Column 3, SCO COG
reg lnwage_w_COG_COD time lnsupply_COG_COD, robust
newey lnwage_w_COG_COD time lnsupply_COG_COD, lag(1)

reg lnwage_w_COG_COD time lnempl_COG_COD, robust
newey lnwage_w_COG_COD time lnempl_COG_COD, lag(1)

reg lnwage_w_COG_COD time lnsupply_COG_COD if year>=1970, robust
newey lnwage_w_COG_COD time lnsupply_COG_COD if year>=1970, lag(1)


**** instrumenting with ethnic groups or immigrants, elasticity between HS and HSD
*** regression mentioned in the text of OP (2008)

gen lnsupply_HS_HSD_hisp=ln(hours_hisp_HSG/hours_hisp_HSD)
gen lnsupply_HS_HSD_immi=ln(hours_immigrants_HSG/hours_immigrants_HSD)

reg lnwage_w_HS_HSD time lnsupply_HS_HSD if year>=1994, robust
ivreg lnwage_w_HS_HSD time (lnsupply_HS_HSD=lnsupply_HS_HSD_hisp), robust
ivreg lnwage_w_HS_HSD time (lnsupply_HS_HSD=lnsupply_HS_HSD_immi), robust